User:Int 80h/files/DOS 6.22 autoexec.bat

autoexec.bat

DOS 6.22 autoexec.bat

:::: autoexec.bat -- DOS 6.22 -- vim: ft=dosbatch
:: Maintainer  : Szymon 'polemon' Bereziak <polemon@gmail.com>
:: Last change : 2016-03-07

@echo off
path C:\WINDOWS;C:\DOS
prompt $p $g  $h

set TEMP=C:\DOS
set HOME=C:\
set BIND=PCNTND
set MTCPCFG=C:\NET\TOOLS\TCP.CFG
set WATTCP.CFG=C:\NET\TOOLS
set DJGPP=C:\DJGPP\DJGPP.ENV
set DJREPO=ftp://ftp.fu-berlin.de/pc/languages/djgpp/current
set TZ=CET1CST

set PATH=%PATH%;C:\ARCHIVER
set PATH=%PATH%;C:\NET\TOOLS
set PATH=%PATH%;C:\DJGPP\BIN
set PATH=%PATH%;C:\VIM\VIM74
set PATH=%PATH%;C:\TASM\BIN

goto %config%

:windows
lh C:\DOS\SMARTDRV.EXE /X

mode con codepage prepare=((852) C:\DOS\EGA.CPI)
mode con codepage select=852
keyb us,852,C:\DOS\KEYBOARD.SYS

lh C:\DOS\MSCDEX.EXE /S /D:MSCD001
lh /L:0;1,3104 /S C:\DOS\CTMOUSE.EXE /B /N /R12
lh C:\WINDOWS\net start
rem call C:\WINDOWS\winpkt.bat C:\WINDOWS\
lh C:\WINDOWS\WINPKT.COM 0x60
goto nothing

:extend
lh C:\CWSDPMI\BIN\CWSDPMI.EXE -p

:normal
lh C:\DOS\SMARTDRV.EXE /X
lh C:\DOS\DOSKEY.COM /REINSTALL /BUFSIZE=1024
lh /L:2,1520 C:\4DOS\KSTACK.COM

mode con codepage prepare=((852) C:\DOS\EGA.CPI)
mode con codepage select=852
keyb us,852,C:\DOS\KEYBOARD.SYS
prompt $e[m$e[32m$p $e[31m$g $e[m

:savesnd
set BLASTER=A220 I5 D1 H5 P330 T6
set SOUND=C:\SB16
set MIDI=SYNTH:1 MAP:E
C:\SB16\DIAGNOSE /S
C:\SB16\MIXERSET /P /Q

:savecd
lh C:\DOS\MSCDEX.EXE /S /D:MSCD001

:savemem
set COMSPEC=C:\4DOS\4DOS.COM
lh C:\NET\NETBIND.COM
lh /L:0;1,3104 /S C:\DOS\CTMOUSE.EXE /B /N /R12
alias /R C:\ALIASES.LST

:nothing

I should explain the BLASTER variable is set to the SoundBlaster™ 16 emulation used in Oracle's VirtualBox™. When installing DOS 6.22 in there, and emulating that sound card, these settings are correct.

It should be noted, that VirtualBox doesn't emulate the MIDI interface, so there's no MIDI device at port 330h. It is set here (for good measure), but is actually superfluous.